Your Script Doctor

To test, run the following script and fail to respond before two minutes have elapsed.

   tell application "Adobe InDesign CC 2014"
      activate
      set userResponse to display dialog "Do you want to continue?" buttons {"Yes", "No"} default button "Yes"
      if button returned of userResponse is "No" then error "User Quit Application"
  end tell

If an AppleScript dialog is not issued from within an application, the dialog box can stay open for as long as you will let it. To test, run the following script and go on to do other tasks on the computer for over two minutes.

   set d to time of (current date)
   set userResponse to display dialog "What is your name?" default answer "" buttons {"OK"}
   set b to time of (current date)
   set timeToAnswer to b - d
   if text returned of userResponse is not "" then
      set userName to text returned of userResponse
      display alert ("Hello " & userName & return & "It took you " & timeToAnswer " & " seconds to respond.")
   end if 

Notice the code in the above that allows the script to determine the amount of time that elapsed before the dialog was dismissed.

Giving Up After

You can limit the time an AppleScript dialog stays open by appending a giving up after statement to a display dialog or display alert. This is often used to provide a dialog that does not require a response.

   display alert "Script is completed" giving up after 3

The result of a dialog set to give up after a number of seconds will return true if the dialog stays open for the allowed amount of time. If the user dismisses the dialog before that time, the result is false. Check AppleScript Editor’s Result panel to see what is returned when you run the following script. First, allow the dialog to stay open until it closes automatically, and second, dismiss the dialog by clicking the OK button.

display dialog "Click OK to dismiss dialog" buttons {"OK"} giving up after 30

With Timeout

Conversely you can extend the amount of time a dialog issued within an application is allowed to stay open using a with timeout statement.

   tell application "Finder"
      with timeout of 500 seconds
         --a process that takes a long time
      end timeout
   end tell

A with timeout statement can be used around a choose file, choose from list, or other AppleScript statements that requires the user to respond.

   set homeFolder to (path to home folder from user domain) as string
   set ccFolder to (homeFolder & "Creative Cloud Files") as alias
   tell application "Adobe InDesign CC 2014"
      with timeout of 500 seconds
         set fileChoice to choose file with prompt "Select Text File" default location ccFolder
      end timeout
      --script continues using file chosen
   end tell

InDesign Custom Dialogs

InDesign Custom Dialogs are also modal in that the script cannot continue, nor can any user activity continue within InDesign until the dialog is dismissed.

If the dialog has a number of fields that could take the user longer than 2 minutes to complete, you might want to give the dialog some extra time using a with timeout statement. The following simplified dialog can be used for testing:

   try
      set userResponse to doDialog()
   on error errStr number errorNumber
      if errorNumber is -1712 then --timeout error
         activate
         display alert "Error: " & errStr
   end try
   (*Sample dialog gives user up to 500 seconds to respond
   Assumes user interaction level of script preferences is set to interact with all*)
   on doDialog()
      tell application "Adobe InDesign CC 2014"
         with timeout of 500 seconds
            set dlgRef to make dialog with properties {name:"Demo Dialog"}
            tell dlgRef
               tell (make dialog column)
                 tell (make dialog row)
                    make static text with properties {static label:"Document Name"}
                    set nameField to make text editbox with properties {min width:200, edit contents:""}
                 end tell
               end tell
            end tell
            set userResponse to show dlgRef
        end timeout
         if userResponse is true then
            set userCancelled to false
            set theResult to edit contents of nameField
         else
            set userCancelled to true
         end if
         destroy dlgRef
         if userCancelled then error ("User Cancelled")
            return theResult
         end tell
      end doDialog 

Notice how the call to the doDialog handler is called from within a try/on error block to handle the error thrown if user dismisses the dialog using the Cancel button. Also, notice how the error number can be used to determine the error that was thrown. Error number -1712 is a timeout error.