Your Script Doctor

After running the script you should have a folder named images_jpg and one named images_PNG at the location designated from the user dialog dropdown (desktop by default).

Export Preferences

Another possible functionality you may want for the script is the option to set export preferences rather than assume they are set as needed. This opens up a whole new set of possibilities. You could:

• Have default settings for the exports written into the script
• Have the user determine if these default settings will need to be set

Lets explore this train of thought.

Add two more checkboxes to the user dialog to indicate the user’s choice for setting jpeg and PNG export preferences. For the last statement block inside the tell (make dialog coloumn) block, add:

tell (make dialog row)
   set jpgPrefs to make checkbox control with properties {static label: "Set jpeg export preferences", checked state: false}
   set pngPrefs to make checkbox control with properties {static label: "Set PNG export preferences", checked state: false}
end tell

Then below the comment that reads “capture results from widgets” add:

set preferencesList to {checked state of jpgPrefs, checked state of pngPrefs}

Lastly, change the return statement for the userDialog handler to read:

return {folderIndex, checkedList, preferencesList}

With this, we can add a call to a handler to set export preferences based on the list of preferences passed back from userDialog. Place this before the last end if in the main portion of the script:

if item 3 of userResult contains true then
   setExportPrefs (item 3 of userResult) 
end if

For the setExportPrefs handler, add the following to the bottom of the script:

on setExportPrefs (exportPrefs)
   tell application "Adobe InDesign CC 2017"
	if item 1 of exportPrefs then
	   set properties of JPEG export preferences to ¬
          {jpeg color space:RGB, JPEG Quality:high, JPEG Rendering style:baseline encoding, ¬
          use document bleeds:true}
	end if
	if item 2 of exportPrefs then
	   set properties of PNG export preferences to ¬
          {PNG color space:RGB, PNG Quality:medium, anti alias:true, export resolution:72, ¬
           Exporting Spread:false, transparent background:true, use document bleeds:true}
	end if
   end tell
end setExportPrefs

You may want to set your export preferences differently. Refer to Script Editor’s Dictionary for InDesign.

Bullet Proofing

Should you test the script without a document open, and select Document folder from the dropdown you will get an error. To handle this, we will add a handler to get a reference to the topmost document (document 1). If a document does not exist, an error is thrown. We will add a trap for this error later.

on getDocRef()
   tell application "Adobe InDesign CC 2017"
	if (count of documents) = 0 then
	   error "Requires open document with graphics for export."
	end if
	set docRef to document 1
   end tell
   return docRef
end getDocRef

Testing for the existence of a document should be done before we even present the user with a dialog. The following statement will now be the second line of the script.

set docRef to getDocRef ()

With all of this code in place, we still have not exported any groups or graphics from our document. As you can see, most of the supporting functionality has been moved to handlers. These handlers can possibly be used many times in other scripts. We have just one more handler to add: doExport, the code that does the actual export. Copy the following to the bottom of the script.

on doExport(docRef, jpgPath, pngPath, choiceList)
   tell application "Adobe InDesign CC 2017"
	tell docRef
	   if item 1 of choiceList or item 2 of choiceList then
		set groupList to every group & every group of every page item
		repeat with i from 1 to length of groupList
		   set itemId to id of item i of groupList
		   set itemClass to class of item i of groupList
		   if itemClass is group then
			if item 1 of choiceList then
			   export item i of groupList to ¬
                           (jpgPath & ":" & itemClass & "_" & itemId & ".jpg") format JPG
			end if
			if item 2 of choiceList then
			   export item i of groupList to ¬
                           (pngPath & ":" & itemClass & "_" & itemId & ".png") format PNG format
			end if
		   end if
		end repeat
	    end if
	    if item 3 of choiceList or item 4 of choiceList then
		set graphicList to all graphics
		repeat with i from 1 to length of graphicList
		   set itemId to id of item i of graphicList
                   set itemClass to class of item i of graphicList
		   if item 3 of choiceList then
			export item i of graphicList to ¬
                       (jpgPath & ":" & itemClass & "_" & itemId & ".jpg") format JPG
		   end if
		   if item 4 of choiceList then
			export item i of graphicList to ¬
                       (pngPath & ":" & itemClass & "_" & itemId & ".png") format PNG format
		   end if
		end repeat
	    end if
	end tell --document
   end tell
end doExport

With this in place we can now finalize the top (main) portion of the script. We will add the following:

• default values for the jpgPath and pngPath variables
• a try statement block to trap any errors
• a call to the doExport handler

The top of the script will now look like the following:

Test Script

set folderList to {"Desktop", "Home Folder", "Document Folder"}
set jpgPath to missing value
set pngPath to missing value
try
   set docRef to getDocRef()
   set userResult to userDialog(folderList)
   set choiceList to item 2 of userResult
   if choiceList contains true then
	set folderPath to getFolderPath(item 1 of userResult)
	if item 1 of choiceList or item 3 of choiceList then
	   set jpgPath to my checkFolder(folderPath, "images_jpg")
	end if
	if item 2 of choiceList or item 4 of choiceList then
	   set pngPath to my checkFolder(folderPath, "images_PNG")
	end if
	if item 3 of userResult contains true then 
           setExportPrefs(item 3 of userResult)
        end if
	doExport(docRef, jpgPath, pngPath, choiceList)
   else
	error "No export choices made"
   end if
on error errMsg
   activate
   display alert errMsg
end try

Notice that we have simplified the main portion of the script from that in the previous blog post. By creating a handler to check for the active document we have put all statements targeted to the application in handlers. This modularizes the script while creating handlers that can be reused in other scripts down the road.