Your Script Doctor

ave the document.

Markup the Document

Marking up your document for a multiple-item XML can be a tedious and error-prone process. To eliminate this, use our script XML_Tag Markup.scpt. The following code assumes that tags, paragraph styles, and all have been set up as described above. Little error checking is provided, so use with caution.

XML_Tag Markup

   set tagName to "Employee"
   tell application "Adobe InDesign CC 2015"
      set docRef to document 1
      tell docRef
         set mTagRef to my getTag(docRef, tagName)
         set selList to selection
         set frameRef to item 1 of selList
         set rootElement to XML element 1
      end tell
      set parentElement to my tagFrame(docRef, frameRef, tagName)
      set paraCount to count of paragraphs of frameRef
      repeat with i from paraCount to 1 by -1
         tell frameRef
            set paraRef to object reference of paragraph i
            set styleRef to applied paragraph style of paraRef
            set styleName to name of styleRef
            set tagRef to my getTag(docRef, styleName)
            set textRef to object reference of text from character 1 to character -2 of paraRef
         end tell
         tell parentElement
            set elementRef to make XML element with properties {markup tag:tagRef}
            markup textRef using elementRef
         end tell
         tell docRef to make XML import map with properties {mapped style:styleRef, markup tag:tagRef}
      end repeat
   end tell --application
   (*Tags the selected text frame. Use with Primary Text Frame selected on page 1*)
   on tagFrame(docRef, frameRef, tagName)
	set masterName to tagName & "s"
	set tagRef to getTag(docRef, tagName)
	set mTagRef to getTag(docRef, masterName)
	tell application "Adobe InDesign CC 2015"
	   tell docRef
	      set rootElement to XML element 1
	      set name of frameRef to tagName
	   end tell
	   tell rootElement
		set masterElement to make XML element with properties {markup tag:mTagRef}
	   end tell
	   tell masterElement
		set parentElement to make XML element with properties {markup tag:tagRef}
	   end tell
	   tell parentElement to markup using frameRef
	end tell
	return parentElement
   end tagFrame
   (*Checks for existence of tag. If it doesn't exist, it is created*)
   on getTag(docRef, tagName)
	set tagRef to missing value
	tell application "Adobe InDesign CC 2015"
	   tell docRef
		if exists XML tag tagName then
		   return XML tag tagName
		else
		   set tagRef to make XML tag with properties {name:tagName}
		end if
	   end tell
	end tell
	return tagRef
   end getTag

Select the text frame with the placeholder text and run the script. When prompted, enter “Employee”. This is the name for the parent element of the XML text elements.

If you did everything right to this point, the Structure panel (Command + Option + 1) and Story Editor (Command+Y with text selected) should look like the following.