Your Script Doctor

Alternatively, you could use a script similar to the following to get the values you are interested in:

   set str to ""
   tell application "Adobe InDesign CC 2015"
      tell PDF export preset "[High Quality Print]"
    	set str to str & "name of applied flattener preset " & name of applied flattener preset
	set str to str & "optimize PDF " & optimize PDF & return
	set str to str & "export reader spreads " & export reader spreads & return
	set str to str & "include hyperlinks " & include hyperlinks & return
	set str to str & "include structure " & include structure & return
	set str to str & "export reader spreads " & export reader spreads & return
	set str to str & "include hyperlinks " & include hyperlinks & return
	set str to str & "include structure " & include structure & return
	--add more statements as needed
	end tell
end tell
str

This script introduces a couple of new concepts:

• variables – The first statement creates a variable identified by str. You might want to think of a variable as the label on the front of a box to identify an item you have stored inside for later use. The identifier for a variable can be any combination of alphanumeric characters. A common convention for naming a variable is to place two words together with the second word designated by a capital letter. This is referred to as camel case as the capital in the middle can look like a camel’s hump.
  For example:
     myVariable
  or a shortened version:
     myVar
• concatenation – This is a word that simply combines objects together. To combine words or strings of characters, the ampersand (&) is used. Notice in the example above, that in each set statement, the string (identified by the variable str) is added to itself. This is followed by text to identify the property, a space, the value for the property, and then a line return (return).

To get a sense of how this works, copy the script above into AppleScript Editor. Make sure you have your version of InDesign running in the background. Compile and then run the script. Check out the result in the editor’s Result panel. Add more statements to get all of the property values you are interested in.

If you find a PDF export preset that sets your PDF Export Preference values the way you want them, you can export a document to PDF using a script similar to the following:

Export to PDF With Preset

   (*Names of presets provided in InDesign for version 2015:
   "[High Quality Print]", "[PDF/X-1a:2001]", "[PDF/X-3:2002]", 
   "[PDF/X-4:2008]", "[Press Quality]", "[Smallest File Size]"*)
   --gets the path to the desktop on the computer
   set desktopFolder to path to desktop from user domain as string
   --adds the name of the file to the path to the desktop
   set filePath to desktopFolder & "samplePDF.pdf"
   tell application "Adobe InDesign CC 2015"
      set myExportPreset to PDF export preset "[Press Quality]"
      tell document 1
	  asynchronous export file format PDF type to filePath using myExportPreset
      end tell
   end tell

Note: asynchronous export is only available with later versions of InDesign. Consult the AppleScript Dictionary for your version of InDesign.

CREATE YOUR OWN PRESET

If you don’t find a PDF export preset that fits your particular need, you can write statements to define your settings individually, or you might decide to create a PDF export preset for a collection of preferences you use repeatedly. To create a preset with a script, you simply make a PDF export preset, give it a unique name, and establish its settings. If you look at the AppleScript Dictionary listing for PDF export preset, you will find that the property listing is similar to that for PDF export preferences. One way to accomplish this is to put a reference to the object being created in a variable and then use the variable as part of a tell statement to set the values for its properties. For example:

   set presetName to "ReaderSpreadPreset"
   tell application "Adobe InDesign CC 2015"
	if not (exists PDF export preset presetName) then
	   set myPreset to make PDF export preset with properties {name:presetName}
	else
	   set myPreset to PDF export preset presetName
	end if
	tell myPreset
	   set crop images to frames to true
	   set export layers to true
	   set export reader spreads to true
	   set open in full screen to false
	   set pdf magnification to actual size
	   set use document bleed with PDF to true	
	end tell
   end tell

Notice that this script uses an if statement to determine if a preset currently exists with the name identified in the variable presetName. If the preset exists, its values are overwritten by those enumerated in the tell myPreset statement block. For a fully functional script you might want to alert the user that the preset values will be overwritten and give the user the option to not override the settings.

Note: When you export a document using a preset, any properties not set by the preset default to those currently set by default.

SECURITY

PDF export preferences that can’t be included in a PDF export preset are those that have to do with security. Security settings are only effective if the property use security is set to true:

   --inside tell statement to PDF export preferences
   set use security to true
   (*the following value can only be set; 
   trying to get its value will produce an error*)
   set change security password to false
   set disallow changing to false
   set disallow copying to false
   set disallow document assembly to false
   set disallow extraction for accessibility to false
   set disallow form fill in to false
   set disallow hi res printing to false
   set disallow notes to false
   set disallow plaintext metadata to false
   set disallow printing to false

APPLIED FLATTENER PRESET

For the most part, the preferences that can be set for PDF export are fairly self explanatory. One that may give you some difficulty is applied Flattener Preset. A Flattener Preset is similar to a PDF Export Preset as it is a collection of properties identified by a given name.

Adobe’s technology for turning a document having transparencies into a form that can be output is called flattening. For this, InDesign provides several flattener presets, a list of which can be returned using:

   tell application "Adobe InDesign CC 2015"
      get name of flattener presets
   end tell

To use a flattener preset certain conditions must exist within the application. Without that, an attempt to set or get values having to do with a flattener or transparency will produce an error. For this reason you will want to place these statements inside a try, end try statement block.

   --assumes the presets referenced exist
   set myError to "" --initialize value for variable to empty string
   tell application "Adobe InDesign CC 2015"
      set myFlattener to flattener preset "[High Resolution]"
      set myPreset to PDF export preset "ReaderSpread"
      tell myPreset
         try
            set ignore spread overrides to true
            set applied flattener preset to myFlattener
        on error errStr
            set myError to errStr
        end try
       --other statements to set for the preset
      end tell
   end tell
   myError

With a number of PDF Export Presets created, you could present your user with a list of presets from which to choose as part of an export to PDF script.

EXPORT TO PDF SCRIPT 

   --expects open document in Adobe InDesign
   set myPrompt to "Choose PDF Export Preset"
   set desktopFolder to path to desktop from user domain as string
   set filePath to desktopFolder & "samplePDFExport.pdf"
   try
      tell application "Adobe InDesign CC 2015"
        --make sure there is a document open
	if (count of documents) is greater than 0 then
	   set docRef to document 1
	else
	   error "Script requires an active document"
	end if
	set presetList to get name of PDF export presets
	set presetList to choose from list presetList with prompt myPrompt without multiple selections allowed
	--make sure user has selected a preset
        if presetList is false then
	   error "Can't continue without preset choice"
	else
	   set presetName to item 1 of presetList --only 1 choice was allowed
	   set myExportPreset to PDF export preset presetName
	end if
        --perform the export
	tell docRef
	   asynchronous export file format PDF type to filePath using myExportPreset without showing options
	end tell
      end tell
   on error errStr
      activate
      display alert errStr
      return
   end try