Your Script Doctor

InCopy to InDesign Workflows

The subject of our last four blogs has concentrated on using an Adobe InCopy to InDesign edit-first workflow. If you have been following along, you may have come to the conclusion that this workflow is just what you need for a project. However, when it comes to working with images and design-intensive documents you may want to start the project inside InDesign (layout-first workflow). The nice thing is, you can use both. You just need to decide on which workflow works best for each situation. One of the decision considerations may be in how you want to handle images.

Images in InCopy

Realize that when you place an image in InCopy or InDesign, what gets placed is a low-resolution representation of the file. Unless you embed the image, the only way the document can output the image is by linking to the file. If the document doesn’t have access to the file, you can be sure that fur will fly. For this reason many operations absolutely do not let InCopy editors touch images.

One of the reasons for using the edit-first workflow is to allow the designer to preplan a project. Additionally, editors can write copy without the constraint of having to fit their prose into a space that only a designer can understand. When your editor decides to manage images (when allowed) or your process needs the depth measurement of the InCopy document to include the image and its caption, you do have options. We will look at a few of them in this discussion.

Heed the Warning

When it comes to working with images in InCopy, the number one rule is that both sides of the workflow need access to the image files. If both have access to a database, just make sure the images are there. With more recent versions of Creative Cloud, you can set up a folder to be collaborative and invite others to participate. This seems to work quite well with an edit-first workflow. The only restriction here is collaborators need to have a Creative Cloud account or Adobe ID. With this they must sign in to their Creative Cloud account, and accept an invitation for each collaboration to which they are invited. (For more information, go to helpx.adobe.com/creative-cloud/help/collaboration-faq.html.) Alternatively you may opt for using Dropbox or other web service.

Inline Image Option

The InCopy user can place an image anywhere within the story flow, it just needs to be inline. For this, a paragraph style and/or character style is set specifically for the inline image (name it “Image” if you will). Set its leading (line spacing) to auto. For the paragraph style, you may also want to set justification, space before and space after values.

If you want the image to be on a line of its own, the insertion point of an empty paragraph is assigned the paragraph style and then used to place the image. For smaller inline images, the active insertion point is assigned a character style having its leading set to auto.

Easy Does It

To make this process easy on your editors, you might want to provide a template. Set this up for the desired text area width and include all the text styles that will be used in the final document. (Use the Paragraph Styles panel to load the styles from your project’s stylesheet.) You will want the template stored in a protected location on the computer. To allow the user easy access to templates, provide a script similar to the following that has been set up to run from a keyboard shortcut. The script uses a folder named Templates inside the application folder. You may decide on a different location.

InCopy Document from Template

   set promptStr to "Choose template for document"
   try
      tell application "Adobe InCopy CC 2014"
         set appPath to file path as string
         set folderPath to appPath & "Templates"
         set templateChoice to my getTemplate(folderPath, promptStr)
         set documentRef to open templateChoice
         activate
         --switch to layout view or change to story view
         set view tab of window 1 to layout view
      end tell
   on error errStr
      activate
      display alert errStr
      return
   end try
  (*Handler returns reference to chosen file; errors if user cancels*)
   on getTemplate(folderPath, promptStr)
      set dLocation to folderPath as alias
      set templateChoice to choose file with prompt promptStr default location dLocation without invisibles
      return templateChoice
   end getTemplate 

Place Image Inline

Later, when needed, the user runs a second script to place the inline image. (It goes without saying that the script should be set up to run from a keyboard shortcut.) The example script below uses a paragraph style named “Image” to make sure leading is set to auto. It allows the user to select the image file from a pre-determined folder and then opens the file. You may think of other tasks that can be added to this script.

   --assumes document has paragraph style named Image
   set myPrompt to "Select image file for placement"
   set errStr to "Requires active insertion point in active document"
   --set your folder structure as needed
   set homeFolder to (path to home folder from user domain) as string
   set workingFolderName to "WorkingFolder:Images"
   set sharedFolder to "Creative Cloud Files"
   set workingFolderPath to homeFolder & sharedFolder & ":" & workingFolderName
   --default location for choosing file
   set dLocation to workingFolderPath as alias
   try
      set insertRef to testDocument(errStr)
      set fileRef to choose file with prompt myPrompt default location dLocation without invisibles
   on error errStr
      activate
      display alert errStr
      return
   end try
   tell application "Adobe InCopy CC 2014"
      tell document 1
         set applied paragraph style of insertRef to paragraph style "Image"
         tell insertRef to place fileRef
      end tell
   end tell
   (*handler verifies document; returns reference to insertion point*)
   on testDocument(errStr)
      tell application "Adobe InCopy CC 2014"
         if (count of documents) is 0 then error errStr
         set selList to selection
         if length of selList = 0 or class of item 1 of selList is not insertion point then
            error "Please have an insertion point active before running this script"
         end if
      end tell
      return item 1 of selList
   end testDocument 

Dummy Image for Placement

If your InCopy editor has a recurring need for a layout with an image having a consistent size, you may decide to include a dummy image in the template. The dummy image can be a low resolution file stored in a subfolder of your Templates folder. This image can easily be replaced with the real image on the InCopy side, or just used to give an accurate readout of the story depth. In the latter instance, the image is replaced by the layout artist.