MAPPING STYLE TAGS

The interesting thing about working with Adobe InDesign is that you can import an XML file and associate its tags with the names of paragraph styles in the document. Paragraph styles can also be associatd with HTML tags used for exporting documents in HTML format.We will demonstrate importing XML with the following sample script. We will leave exporting as HTML for later.

INDESIGN TEMPLATE

Our sample script will create a document from a template that has paragraph styles named the same as the XML tags used in the XML file. It also has a predefined table style named “GrayHead”. The template will be an InDesign template (.indt) stored in a folder named Templates inside the InDesign application folder. (If you do not have administration privileges, you will need to use another location.) If you ar following along, make sure your template has the following styles:

Paragraph Styles:
Head, Text_10, Label, Table_Head, Table_Body.

Table Style: GrayHead.

Cell Styles: Head (for the first row), Body (for all cells except the left region and right region), LeftCol (for the left region), RightCol (for the right region).

How you define these styles is up to you.

SAMPLE SCRIPT

We will take the script one step at a time. In case you have problems we will post a download of the files on the AppleScript page of this web site.

Define Variables

Define variables that can be changed by the user at the top of a script. Later, when the script is working as designed, these can be replaced by a user interface using InDesign’s custom dialog.

set elementName to "table"
set tableStyleName to "GrayHead" 
set doLink to false --should XML file be linked

Have User Select Template

This part of the script will be taken care of (handled) by a handler getTemplate. The call to the handler places the result passed back by the handler into the variable templateRef. The handler uses a choose file command.

   --the call to the handler
   set templateRef to getTemplate()
   (*Template file selected by user is returned from handler; otherwise an error is thrown*)
    on getTemplate()
	tell application "Adobe InDesign CC 2015"
		set appPath to file path as string
	end tell
	set templatePath to (appPath & "Templates:") as alias
	set templateRef to (choose file with prompt "choose template for document" default location templatePath without invisibles)
	return templateRef
	error "User Cancelled"
    end getTemplate 

Establish Reference to XML File Chosen by User

The script will use a choose file command to have the user identify the XML file for import. Notice how both choose file commands incorporate a default location parameter. This requires an alias reference to the folder where the file will be found. For simplicity we used the path to the user’s desktop, but you may wish to use another path.

    --establish folder path for XML file
    set homePath to path to desktop from user domain
    --define XML file to import
    set fileRef to choose file with prompt "Select XML file for import" default location homePath without invisibles 

Create Document and Import XML

Once the script has a reference to the template and the XML file to place, the document is created. A reference to the document is placed in the variable docRef. The script then tells the document (docRef) to import the XML file using the reference to the XML file (fileRef)

    tell application "Adobe InDesign CC 2015"
        tell XML import preferences
		set import style to merge import
		set import CALS tables to false
		set repeat text elements to false
		set create link to XML to doLink
	    end tell
        set docRef to open templateRef
        tell docRef
           import XML from fileRef
        end tell
    end tell

If you run the script at this point and open the document created, you will see the structure of the XML file in Adobe’s Structure Pane (View > Structure > Show Structure). You will need to click on the small arrows next to the Root element and the to disclose the elements (and their contents) in the structure.

Root
   Head
   Text_10
   table  
        td
        td
        ...
   Text_10

Place XML on the Page

To place an XML structure on a page, there are a number of conventions that can be used in InDesign. Our example will use the XML root element as part of a place XML command. The statement places the imported XML to the first page of the document. As a consequence of the place XML statement, the XML will be placed in a text frame positioned at one-half inch from the left and top of the page (place point). A reference to the text frame created is placed in the variable frameRef.

    --after the import statement inside the tell docRef code block
       set rootElement to XML element 1
    end tell --ends tell docRef block
    tell page 1 of docRef
       set frameRef to place XML using rootElement place point (".5 in", ".5 in"}
    end tell 

Style Text

To style the document text, the script will associate paragraph style names with the text contained by the XML elements using the name of their tags. Another handler will accomplish this task. It takes advantage of the fact that the names of the paragraph styles in the document are the same as the XML tags.

Notice that the call to the handler begins with the reserved word my. This is required as the call is inside a tell statement to the application. The handler associates the paragraph styles to the XML element contents by creating an XML import map. Once the map is created, the script executes the map XML tags to styles method.

    --call mapTags handler passing a reference to the document
   my mapTags (docRef)
   (*Associates tags in document's list of XML tags with corresponding Paragraph styles
    Uses XML tag to style to map styles.*)
    on mapTags(docRef)
        tell application "Adobe InDesign CC 2015"
	    tell docRef
	        set tagList to XML tags
	        repeat with i from 1 to length of tagList
		    set tagName to name of item i of tagList
		    if (exists paragraph style tagName) then
		        set styleRef to paragraph style tagName
		        make XML import map with properties {mapped style:styleRef, markup tag:item i of tagList}
		    end if
	        end repeat
	        map XML tags to styles
	    end tell
        end tell
    end mapTags 

Create and Style the Table

All that is left for the script to do is to create and style the table, the script first needs to get a reference to the XML element whose markup tag is named “table”. For this we will use a handler to identify the element. It is important to note here that XML elements do not have a name property. XML elements are referenced in order as child elements in the XML structure. This is similar to items within a list (or list of lists). The following handler accomplishes this task by looping through the number of elements found in the first level of XML elements (child elements of Root). When the required element is found, the loop exits. If the Table element were to be nested at another level in the structure, the handler would need to be written much differently. Remember that the name to associate with our table XML element (elementName) and the name of the table style (tableStyleName) were defined at the top of the script.

    --place this code before the last end tell statement
    tell docRef
       set tableElement to my getXMLElement(rootElement, elementName)
    end tell
    set tableStyleRef to table style tableStyleName of docRef
    --get width of table's container to set width of the table
    copy geometric bounds of frameRef to {fy0, fx0, fy1, fx1}
    set frameWidth to fx1 - fx0
    --convert the contents of the XML "table" element to a table
    tell tableElement to convert element to table row tag "tr" cell tag "td"
    tell tables of frameRef
        set row type of row 1 to header row
        set applied table style to tableStyleRef
        set width to frameWidth
        tell cells to clear cell style overrides
    end tell
    (*Returns reference to XML element tagged with value of variable elementName*)
    on getXMLElement(rootElement, elementName)
   	set foundElement to missing value
	tell application "Adobe InDesign CC 2015"
	    repeat with i from 1 to count of XML elements of rootElement
		if name of markup tag of XML element i of rootElement is elementName then
		    set foundElement to XML element i of rootElement
		    exit repeat
		end if
	    end repeat
	    if foundElement = missing value then
		error "Element " & elementName & " was not found"
	    else
		return foundElement
	    end if
	end tell
    end getXMLElement