Your Script Doctor

Understanding that a catalog page could feature a single item or any number of items up to twelve (3 rows and 4 columns), using a script to automatically divide the product information area of the page makes a lot of sense. A simplified version of this script is our Feature Script for this month (see our AppleScript page).

Eliminate Folder Diving

Save your templates to a specific location on the computer hard drive. Using this location, a script can then create new documents using a chosen template. One location of choice for the Template folder is inside the folder for the application. This allows the script to create the path to the template folder using the application’s file path.

—call to handler to get path to Template folder
   set folderName to "Templates"
   set fileTypeList to {"IDm7", "ID7t", "ID8t", "ID9t", "IDXt"}
   set thePrompt to "Choose template file from list"
   try
      set templatePath to getTemplatePath(folderName)
   on error errStr
   activate
      display alert errStr
   end try
(*Returns path to folder named residing in application folder; if folder not found error is raised*)
on getTemplatePath(folderName)
	tell application "Adobe InDesign CC 2014"
		set appPath to file path as string
		set templatePath to appPath & folderName
	end tell
        return templatePath      
end getTemplatePath

Using the path returned from the handler, the script then gets a list of the files in the folder. The call to this handler is placed inside the try block after the call to getTemplatePath(). Handlers are placed together at the bottom of the script.

 --call to handler to get list of files in the folder
   set fileList to getFiles(templatePath, fileTypeList)
   --returns list of file names found in folder by file type
   on getFiles(templatePath, fileTypeList)
	tell application "Finder"
		set templateNames to name of every file of folder templatePath whose file type is in fileTypeList
		return templateNames
	end tell
   end getFiles

The user then chooses the template from the list which the application uses to create the new document. The call to this handler is placed directly below the call to getFiles().

  --call to docFromTemplate handler
    if length of fileList is greater than 0 then
       set docRef to docFromTemplate(templatePath, thePrompt, fileList)
    end if
   --creates document from template chosen; if no file chosen error 
   on docFromTemplate(templatePath, thePrompt, fileList)
	set fileChoice to choose from list fileList with prompt thePrompt without multiple selections allowed
	if class of fileChoice is list then
		tell application "Adobe InDesign CC 2014"
			set docRef to open file (templatePath & ":" & fileChoice)
		end tell
	else
		error "No document chosen"
	end if
   end docFromTemplate

The script can be modified as needed to define the location for your templates if your folder is located elsewhere. For a list of other standard locations on your computer that can be used for saving files, open the dictionary for StandardAdditions and enter Path to in the search field.

The file types defined for the variable fileTypesList should cover all templates from InDesign CS5.5 to InDesign CC 2014. If your script does not return a list of files, you may need to verify the file type for your templates. The following will return the file type for the first file in a folder chosen. Run the script and choose your Templates folder.

   set theFolder to choose folder
   tell application "Finder"
	set testType to file type of file 1 of theFolder
   end tell
   testType

Looking Forward

To make your DocFromTemplates script even more usable, you might want to have it save the document, named and date-stamped, to a pre-defined folder. This will involve a more involved user interface than just a choose from list dialog. We will look at this next time.